I got this error
Syntax error in .DC command.
expected sweep starting value of source 'sweep'
I have no idea about how the syntax works. I only resorted in asking this site because it was urgent
And here is the code in question:
FILE: p-Enhancement ISFET Model
*********************************************************
*------ ISFET MACROMODEL -------*
*********************************************************
.PARAM
*-------------------------------------------
* Constants and common parameters
*-------------------------------------------
* k = Boltzmann constant [J/k]
* T = Actual absolute temperature. [K]
* q = Electronic charge [Coulomb]
* eps0 = Vacuum dielectric permittivity [F/m]
* epsw = Relative permittivity of the bulk (diffuse layer) solution
* NAv = Avogadro constant [1/mole]
* Lisfx = Gate length [m]
* Wisfx = Gate width [m]
* Agate = Gate area [m**2]
* Cbulk = Electrolyte concentration [mole/l]
* Ka = Positive dissociation constant [mole/l]
* Kb = Negative dissociation constant [mole/l]
* Kn = Dissociation constant for amine sites [mole/l]
* Nsil = Silanol (or oxide) surface site density [#/m**2]
* Nnit = Amine surface site density [#/m**2]
* Eabs = Absolute potential of the standard hydrogen electrode [V]
* Erel = Potential of ref-electrode(Ag/AgCl) relative to H electrode [V]
* Phim = Work-function of metal back-contact/electronic charge [V]
* Philj = Liquid-junction potential diff. between ref-sol. and electrolyte [V]
* Chieo = Surface dipole potential [V]
* Eref = (Eabs+Erel-Phim+Chieo+Philj) acts for gate-source ISFET Voltage [V]
*-----------
+ conv=1e3 conv2=1e6
+ k=1.38e-23 eps0=8.85e-12 T=300
+ q=1.602e-19 NAv=6.0221415e23 ET='q/(k*T)'
+ PI='355/113' PI2='2.0*PI'
+ Nsil=1.0e18 Nnit=9.0e17 ;Si3N4
+ Ka=15.8 Kb=63.1e-9 Kn=1e-10 ;Si3N4
*+ Nsil=8.0e18 Nnit=0.0 *Al2O3
*+ Ka=12.6e-9 Kb=79.9e-9 Kn=0.0 *Al2O3
*+ Nsil=1.0e18 Nnit=0.0 *SiO2
*+ Ka=15.8 Kb=63.1e-9 Kn=0.0 *SiO2
*
+ epsw=78.5 epsihp=32 epsohp=32
+ dihp=0.1n dohp=0.3n Cbulk=150m
+ Eabs=4.7 Phim=4.7 Erel=0.205
+ Chieo=3e-3 Philj=1e-3
+ Lisf1=8u Wisf1=30u Agate='Wisf1*Lisf1'
+ bb='sqrt(8*eps0*epsw*k*T)'
+ Cb='NAv*Cbulk*conv'
+ KK='Ka*Kb*conv2'
+ Ch='(Agate)*((eps0*epsihp*epsohp)/(epsohp*dihp+epsihp*dohp))'
+ Cd='(Agate)*(bb*ET*0.5)*sqrt(Cb)'
+ Ceq='(1/(1/Cd+1/Ch))'
*
**************************************
*** MOSFET MODEL ***
**************************************
* ENHANCEMENT-MODE P-MOSFET
*-------------------------------------
.MODEL MISFET PMOS LEVEL=2
+ PHI=0.7 TOX=39n XJ=0.20u TPG=1
+ VTO=-0.98 DELTA=2.9 LD=58.7n KP=1.68e-5
+ UO=189 UEXP=0.24 UCRIT=1.15e5 RSH=0.1
+ GAMMA=0.64 NSUB=9.86e15 NFS=1.47e11 NEFF=1.5
+ VMAX=10.0e5 LAMBDA=4.25e-2
+ CGSO=0.185n CGDO=0.185n CGBO=0.43n CJSW=0.26n
+ CJ=3.40e-4 MJ=0.58 MJSW=0.31 PB=0.90
*
*****************************************************************
.SUBCKT ISFET 1 6 2 3 4 101
*
Vref 1 10 {Eabs+Erel-Phim+Chieo+Philj}
*
Ceq 10 2 {1/(1/Cd+1/Ch))}
RCeq 10 2 1G
*
EP1 46 0 V = log(KK)+4.606*V(101)
RP1 46 0 1000G
EP2 23 0 V = log(Ka*conv)+2.303*V(101)
RP2 23 0 1000G
*
EPH 2 10 V = (Agate*q/Ceq)*(Nsil*((exp(-2*V(2,10)*ET)-exp(V(46)))/(exp(-2*V(2,10)*ET)+exp(V(23))*exp(-1*V(2,10)*ET)+exp(V(46))))+Nnit*((exp(-1*V(2,10)*ET))/(exp(-1*V(2,10)*ET)+(Kn/Ka)*exp(V(23)))))
RpH 101 0 1K
*************************************************************
MIS 6 2 3 4 MISFET L='Lisf1' W='Wisf1'
*
.ENDS ISFET
****************************************
VpH 500 0 DC 7.3
Vds 450 0 DC -2.5
Vgs 400 0 DC -2.0
*
****************************************
*
XIS 400 450 430 0 0 500 ISFET
*
***********************************
.OPTIONS list node post probe pathnum itl5=200000 tnom=27 ingold=1
.DC VDS 0 -10 1E-2 SWEEP VGS 0 -2.5 0.5
.PROBE DC I(Vds)
.OP
.END
Best Answer
There are some helpful suggestions here. Some of them apply in your case.
LTspice .OPTIONS doesn't support the following, so remove them:
itl5
pathnum
probe
node
ingold
post
That should get you into running mode, anyway.
However, I'd recommend removing everything from the .OPTIONS and below, when pasting it into LTspice. This sets up your models and subcircuits and circuit, without actually specifying which run you want to perform.
Then separately, set up the .OPTIONS card in a spice "text" card that you add, separately on the schematic. Similarly, place the .DC card into its own spice "text" card. And then similarly again, place the .PROBE and .OP cards into yet another spice "text" card, but in this case I'd recommend telling LTspice that this pair of cards are just "comments" for now. You can then run the .DC simulation and display plots, if you want. Afterwards, just comment out the .DC card and uncomment the .PROBE and .OP cards and run it again.