AppCmd to create a virtual directory in default web site in IIS7

iis-7scripting

I try to create a virtual directory under the "Default Web Site" in IIS 7 using AppCmd.

But first I'd like to see if one already exists. How can I use AppCmd to create a virtual directory under the "Default Web Site" and how can I do an if-statement?

Best Answer

Try this:

@ECHO OFF
REM --------------------------------------------------------------------------------
REM Check for and create VDir under Default Web Site
REM
REM %1 is the VDIR to create
REM %2 is the Physical path to the VDIR 
REM --------------------------------------------------------------------------------

IF "%1"=="" GOTO Syntax
IF "%2"=="" GOTO Syntax

ECHO Running...
ECHO   AppCmd.exe list vdir "Default Web Site/%1/"
ECHO.
AppCmd.exe list vdir "Default Web Site/%1/"
IF %errorlevel%==1 GOTO Exists

ECHO.
ECHO Running...
ECHO   AppCmd.exe ADD vdir /app.name:"Default Web Site/" /path:/%1 /physicalPath:%2
ECHO.
AppCmd.exe ADD vdir /app.name:"Default Web Site/" /path:/%1 /physicalPath:%2

GOTO End

:Exists
ECHO.
ECHO VDir already exists
ECHO.
GOTO End

:SYNTAX
ECHO.
ECHO VDir Name and Physical Path Required
ECHO.
ECHO CreateVDir.CMD ^<VDirName^> C:\PhysPath
ECHO.

:END

Related Solutions

Using appcmd to add new web site issue

If you're trying to do this from code, I would recommend Microsoft.Web.Administration instead of appcmd. However, if you're doing it from the command line then appcmd is what you need.

Additionally if you have access to the server, why are you using vdirs for sites instead of full sites? You may find that full sites are cleaner. It depends on your situation, of course.

To do it with appcmd, it would be something like this:

First, make sure that the folder is created. You can do that with the old command line 'md'
Then create the 'application'. It will use the default app pool, not the one of its parent. It's a bit more work to figure out the app pool of the parent first. It would be something like:

appcmd add app /site.name:"sitename" /path:/foldername
Then create the 'vdir'.

appcmd add vdir /app.name:"sitename/foldername" /path:/ /physicalpath:c:\inetpub\wwwroot\foldername

How to Assign Permissions to ApplicationPoolIdentity Account

Update: The original question was for Windows Server 2008, but the solution is easier for Windows Server 2008 R2 and Windows Server 2012 (and Windows 7 and 8). You can add the user through the NTFS UI by typing it in directly. The name is in the format of IIS APPPOOL\{app pool name}. For example: IIS APPPOOL\DefaultAppPool.

IIS APPPOOL\{app pool name}

Note: Per comments below, there are two things to be aware of:

Enter the string directly into the "Select User or Group" and not in the search field.
In a domain environment you need to set the Location to your local computer first.

Reference to Microsoft Docs article: Application Pool Identities > Securing Resources

Original response: (for Windows Server 2008) This is a great feature, but as you mentioned it's not fully implemented yet. You can add the app pool identity from the command prompt with something like icacls, then you can manage it from the GUI. For example, run something like this from the command prompt:

icacls c:\inetpub\wwwroot /grant "IIS APPPOOL\DefaultAppPool":(OI)(CI)(RX)

Then, in Windows Explorer, go to the wwwroot folder and edit the security permissions. You will see what looks like a group (the group icon) called DefaultAppPool. You can now edit the permissions.

However, you don't need to use this at all. It's a bonus that you can use if you want. You can use the old way of creating a custom user per app pool and assigning the custom user to disk. That has full UI support.

This SID injection method is nice because it allows you to use a single user but fully isolate each site from each other without having to create unique users for each app pool. Pretty impressive, and it will be even better with UI support.

Note: If you are unable to find the application pool user, check to see if the Windows service called Application Host Helper Service is running. It's the service that maps application pool users to Windows accounts.

Best Answer

Related Solutions

Using appcmd to add new web site issue

How to Assign Permissions to ApplicationPoolIdentity Account

Related Topic