Mapped Drive by OU

Ah, sounds like an ex-NetWare shop. They were always fond of drive letters.

Windows doesn't track where they come from, unfortunately, so you're left with the forensic task of looking at everything that can cause a script to be mapped. That's a long slog, and I feel for you. There are many:

• GPO direct maps
• GPO indirect maps through scripts
• Local registry-based persistent maps (can also be set via GPO when a BOFH is involved, swearing is permitted in these cases)

For tracking GPOs, the way that works for me is to:

• Launch the GPO Manager
• Go to Group Policy Results
• Right click on it and pick Group Policy Results Wizard
• Pick a user and computer object you want to check (pick someone with 15 mappings)
• Review the resulting report, and go to the Settings tab
• Note any scripts and their associated GPOs
  • Later on, go to each GPO and review the scripts
  • Check for mappings in the scripts
• Note any drive mappings under User -> Preferences -> Drive Maps, and their associated GPOs.
• Dig through for the various places you can set Registry settings, validate if they have [HKCU/Network/$something$] in them.

That'll give you a big start on the source of the drive-mappings that's coming from automation you manage. You can't do much about stuff users do themselves, some never clear the "remember this mapping" button.

Group Policy Preferences work great on Vista and newer OS. If your environment is all Vista or newer, use Preferences. It's straight forward, easy, and works. Preferences will not work on XP unless you have the XP CSE installed. Even with the CSE many people have reported "issues" with them working reliably. GPP is not available for older OSes than XP SP2.

Edit:
Here's a copy of the MapDrives.vbs script we use. Works flawlessly on WinXP/Vista/7/2003/2008/R2.

' Author: Chris Stone
' Date: 29 MAY 2009  Version: 1.3
' Purpose: Map network drives

On Error Resume Next
Set objNet = CreateObject("WScript.Network")

Public Sub CheckAndMapNetDrive(Letter, Path, Persist)
    'Check if drive letter is already used
    Set colNetDrives = objNet.EnumNetworkDrives
    For i = 0 To colNetDrives.Count - 1 Step 2
        If colNetDrives.Item(i) = Letter Then
            'Drive Letter Exists, Test if it's the same Path
            If colNetDrives.Item(i+1) = Path Then
                'It's the same, no new mapping necessary.
                Exit Sub
            Else
                'It's different, remove old.
                objNet.RemoveNetworkDrive colNetDrives.Item(i)
            End If
        End If
    Next
    'Drive does not exist now, never did or removed.
    objNet.MapNetworkDrive Letter, Path, Persist
End Sub 

CheckAndMapNetDrive "X:", "\\server\share1", True
CheckAndMapNetDrive "Y:", "\\server\share2", True