Disable output escaping not working for attribute in xslt

attributesxslt

I have the following xml-node :

<name>P &amp; P</name>

And following XSL

<a href="example.htm" >

    <xsl:attribute name="title">
       <xsl:value-of select="name" disable-output-escaping="yes"></xsl:value-of>
    </xsl:attribute>    


     <xsl:value-of select="name" disable-output-escaping="yes"></xsl:value-of>
</a>

That compiles to this HTML

<a href="example.com" title="P &amp;amp; P">
  P &amp; P
</a>

So the non-escaping worked for the value (the text between <A></A>) but not for the attribute.

Am I missing something here?

Thanks!

Best Answer

From an OP's comment:

I need this xml (P & P) in the title attribute of an HTML tag. A better solution is most welcome!

What you need to generate can be done perfectly without D-O-E.

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
     <a href="example.htm" title="{.}">
       <xsl:value-of select="."/>
     </a>
 </xsl:template>
</xsl:stylesheet>

When applied on the following XML document:

<t>P &amp; P</t>

the wanted, correct result is produced:

<a href="example.htm" title="P &amp; P">P &amp; P</a>

Related Solutions

XSLT character-escaping query

This cannot be done with XSLT. The spec says:

It is an error for output escaping to be disabled for a text node that is used for something other than a text node in the result tree.

Thus it makes no difference if you use Attribute Value Templates or xsl:attribute with xsl:value-of, because you're generating an attribute node, not a text node. It's a limitation in the language.

Xml – Transforming XML mixed nodes with disable-output-escaping

If I understand you right, you want text nodes to come out as literal text (disable-output-escaping="yes"), but the rest of the transformation should work normally (<bold> to <b> etc.)

Template modes can help:

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:output method="xml" encoding="utf-8" omit-xml-declaration="yes" />

  <xsl:template match="paragraph">
    <p>
      <xsl:apply-templates mode="literal" />
    </p>
  </xsl:template>

  <!-- literal templates (invoked in literal mode) -->
  <xsl:template match="bold" mode="literal">
    <b><xsl:apply-templates mode="literal"/></b>
  </xsl:template>
  <xsl:template match="italic" mode="literal">
    <i><xsl:apply-templates mode="literal"/></i>
  </xsl:template>
  <xsl:template match="text()" mode="literal">
    <xsl:value-of select="." disable-output-escaping="yes" />
  </xsl:template>

  <!-- normal templates (invoked when you don't use a template mode) -->
  <xsl:template match="bold">
    <b><xsl:apply-templates /></b>
  </xsl:template>
  <xsl:template match="italic">
    <i><xsl:apply-templates /></i>
  </xsl:template>

</xsl:stylesheet>

Best Answer

Related Solutions

XSLT character-escaping query

Xml – Transforming XML mixed nodes with disable-output-escaping

Related Topic