Google Sheets Query – How to Select One Column in a Query Only If Another Column Has a Specific Value

google sheetsgoogle-sheets-query

I just discovered the query function and it's a huge game-changer. I've been tinkering a little but would love some help with this one. What I would like to do is

=query(
  'Sample Data'!A3:D10, 
  "select A, C where (B='neighborhood')" and "select D where (D='cuisine')"
)

Even if D is populated, it is irrelevant for this query for any other value so I'd like to leave the cell blank in that case.

Is this possible? I've tried a few options and left them in the sample sheet [linked below] to tinker with

I made a quick Sheet of sample data as requested and in the process I thought of a better sample use-case. Sorry for the confusion changing the description, but I think this use case makes more sense to more people.

Best Answer

Short answer

Make two queries and use IF, IERROR, ARRAYFORMULA and the array handling feature of Google Sheets.

Extended answer

It's not possible to get the desired result using a single QUERY because of the Google Query implementation. Fortunately the desired result could be obtained by using other Google Sheets features.

From the linked spreadsheet in the question

What I would like is a single query that would let me output all of the restaurants in a given neighborhood.
Then for each result, IF the restaurant matches a certain cuisine then display the cuisine. if it does not, then leave the cell blank. Bonus points for sorting the output with desired cuisine on top, but that may be asking too much and is really not important. So if I am in Strathcona and hungry, I can get a list of all the places I've "been meaning to go to" in the area, and tonight I'm in the mood for Italian so:

I would like this output:

Poor Italian    1816 Howard St  Italian  
Lucy's          15 Main   
Parallel 49     123908 Main

The following formula returns the desired output:

=ArrayFormula(
  {
    query('Sample Data'!A3:F10,"select A,C where B = 'Strathcona'"),
    if(
      query('Sample Data'!A3:F10,"select D where B = 'Strathcona'")="Italian",
      "Italian",
      IFERROR(1/0)
    )
  }
)

Remarks: In order to make simple formula the neighbourhood and cuisine are "hardcoded" in the formula. In order to make the formula more easy of maintain, this values could be replaced by cell references but you should be aware that the query argument requires that strings be enclosed by using apostrophes.

Assume that A1 holds the value of the neighbourhood. In the formula, the "hardcoded" value 'Strathcona' could be replaced by '&A1&'

By the other hand, the case of the cuisine is out of the query argument, so it could be replaced by just the cell reference. Assume that B1 holds de the value of cuisine. In the formula, the "harcoded" value "Italian" could be replaced by B1

References

Using arrays in Google Sheets - Google Docs editors Help

^{Note to self}

Related Solutions

Sum Column Only if Another Column is Empty in Google Sheets

Replace ISEMPTY with ISBLANK

Your formula should be as follows:-

=SUM(FILTER(A:A, ISBLANK(B:B)))

Now you will get the result as 40

Google-sheets – Columns populated with the number of times each row has the first, second or third largest value for any given column

Unfortunately filter() unique() and similar are not structured to work on individual cells within a 2 dimensional range, they tend to return rows or columns. The following works as long as you do not skip ranks and every row in the data set is accounted for in the ranking

For this the output goes in A2:C6 and the data is in G2:K6

This formula can be entered into the top cell of the "1st" column, A2, and dragged down the column

=countif($G2:$K2,"="&large($G$2:$K$6,1))

it counts the number of occurrences of the largest number in the data set.

Because largest() does not provide unique values we need to skip past all of the instances of the highest value to get to the second highest. Fortunately we just counted the instances of the highest value by row. We will take the sum() of that data to get us to the second largest unique value.

This formula can be entered into the top cell of the "2nd" column, B2, and dragged down the column

=countif($G2:$K2,"="&large($G$2:$K$6,sum(A$2:A$6)+1))

The third rank is similar but we need to sum both of the preceding columns:

=countif($G2:$K2,"="&large($G$2:$K$6,sum(A$2:B$6)+1))

The use of sum() here is a short cut taking advantage of the way you are structuring your output. A version of the 3rd column formula that can exist independently would look like this(using input range of G31:K35):

=countif($G32:$K32,"="&large($G$31:$K$35,countif($G$31:$K$35,">="&large($G$31:$K$35,countif($G$31:$K$35,"="&large($G$31:$K$35,1))+1))+1))

the nesting of countif()'s and large()'s gets deeper and deeper for each successive rank.

https://support.google.com/docs/answer/3093480?hl=en&ref_topic=3105474